Salesman

Discussion in 'Requests' started by Shekhar Sharma, Jul 17, 2016.

         
  1. Shekhar Sharma

    Shekhar Sharma New Member


    I am a new trader.
    I just want to add salesman name in my sales voucher, and salesman wise outstanding.
    I am using Tally ERP9

    Can Someone Help.

    Thanks
     



  2. Mahesh Sethi

    Mahesh Sethi Member


    I have a solution send me your mail id
     



  3. sattam

    sattam Member


    search this forum.You will got more like this.
     



  4. Shekhar Sharma

    Shekhar Sharma New Member




  5. Shekhar Sharma

    Shekhar Sharma New Member


    I have searched but coundn't find appropriate thing.
     




  6. you can add salesman name with below code

    [#Line: VCH Ref]
    Add:Field:After:VCH RefCombo:RefDate

    [Field:RefDate]

    Fields : Simple Prompt, RefDate1
    Inactive : NOT @@VchHasRef
    Invisible : @@IsOrderVch OR (@@IsDebitNote AND @@IsExciseClassJrnl)
    Local : Field : Simple Prompt : Setas : $$LocaleString:"Salesman Name" + ":"
    Local : Field : Simple Prompt : Inactive : NOT @@VchHasRef
    Local : Field : Simple Prompt : Invisible : @@IsOrderVch OR NOT @@VchHasRef


    [Field: RefDate1]

    Use :UniDateField
    Storage : RefDate1
    Inactive : NOT @@VchHasRef
    Invisible : @@IsOrderVch

    [System:udf]
    RefDate1:Date:1005


    Thanks!
    www.aaradhyaasolutions.in
     



  7. sattam

    sattam Member


    ;==================================================Salesman in Sales & Report=======================================
    ;;=============== Saleman Name Master Table==============
    [#Part: CMP AccFeat Left]
    Add: Line: CMP EnableSalesmanTable

    [Line: CMP EnableSalesmanTable]
    Field: Medium Prompt, CMP EnableSalesmanTable
    Local: Field: Medium Prompt: Info: "Enable Salesman ? "
    Local: Field: Long Prompt: Info: "Enable Broker wise Report.?:"
    ;;Does not work in Tally ERP 9
    ;;Invisible: NOT $$MODAdvInventory or NOT $IsInvoicingOn
    Space Top: 1

    [Field: CMP EnableSalesmanTable]
    Use: Logical Field
    Storage: EnableSalesman
    Set as: If $$IsEmpty:$$Value then "No" else $$Value
    Sub Form: SmReport: $$Value = "Yes"

    [#Menu: Gateway Of Tally]

    Add : Item : Salesman : Menu : SalesmanMenu

    [Menu: SalesmanMenu]
    Add : Item : Salesman Master : Alter : Salesman Name
    Add : Item : Blank
    Add : Item : Salesman Sales Report : Display : SmReport
    Add : Item : Blank


    [Report: Salesman Name]
    Form : Salesman Name
    Object : Company

    [Form: Salesman Name]
    Part : FormSubTitle, Saleman
    ;Button : Delete All, Remove Line, Restore Line, Restore All,Report Operations
    FullWidth : No
    Height : 90% Screen
    Background : @@SV_CHEQUE
    SpaceRight : 0.5
    SpaceLeft : 1.5
    Local : Field : Form SubTitle : Info : $$LocaleString:"Salesman Name"
    Option : Small Size Form


    [Part: Saleman]
    Lines : CMP Salesman
    Repeat : CMP Salesman:mydbsalesman
    Break on: $$IsEmpty:$SalesmanName
    Scroll : Vertical
    Height : 90% Screen

    [Line: CMP Salesman]
    Fields : Multi SNo, CMPSalemanName, CMPSalMobNum
    Local : Field : Default : Delete : Border

    [Field: CMPSalemanName]
    Use : Short Name Field
    Storage : SalesmanName
    Unique : Yes


    [Field: CMPSalMobNum]
    Use : Short Name Field
    Storage : SalMobNum
    Unique : Yes

    [System: UDF]
    mydbsalesman : Aggregate: 999
    SalesmanName : String : 1000 ;: Yes
    SalMobNum:String: 1100

    [Collection : SalesmanNameCollection]
    Type : mydbsalesman : Company
    Childof : ##SVCurrentCompany
    Format : $SalesmanName, 10
    Title : Salesman Name

    [Collection : SalesmanMobNumCollection]
    Type : mydbsalesman : Company
    Childof : ##SVCurrentCompany
    Format : $SalMobNum, 10
    Title : Salesman Mobile Num



    ;=============== During Sales Voucher Entry=============

    [#Part: EI BaseInfo]
    Option: HPSalesmanName: $$IsSales:##SVVoucherType OR $$IsCreditNote:##SVVoucherType
    Option: HPSalesmanArea: $$IsSales:##SVVoucherType OR $$IsCreditNote:##SVVoucherType

    [!Part: HPSalesmanName]
    Add: Line: HPSalesmanName

    [Line: HPSalesmanName]
    Add: Field: HPSalesmanNameTitle
    Add: Field: VCHSalesmanName, VCHSalMobNum

    [Field: HPSalesmanNameTitle]
    Info : "Salesman: "
    Width: 10
    ;;This is where the User will input the "Salesman"


    [Field: VCHSalesmanName]
    Use : Name Field
    Storage : VCHSalesmanName
    Set as : $VCHSalesmanName
    Width : 25
    Table : SalesmanNameCollection, not applicable
    Show Table: Always
    Key : Create SalesmanName

    [Key: Create SalesmanName]
    Key :Alt + C
    Action: Alter: SalesmanName

    [System: UDF]
    VCHSalesmanName:String:375

    [Field: VCHSalMobNum]
    Use : Name Field
    Storage : VCHSalMobNum
    Width : 25
    Table : SalesmanMobNumCollection, not applicable
    Show Table: Always
    ;;;;;;Key : Create SalesmanMobNum
    ;;;;;;Set as : $SalMobNum:$mydbsalesman :$VCHSalesmanName

    [System: UDF]
    VCHSalMobNum:String: 388

    [!Part: HPSalesmanArea]
    Add: Line: HPSalesmanArea

    [Line: HPSalesmanArea]
    Add: Field: HPSalesmanArea
    Add: Field: VCHSalesmanArea

    [Field: HPSalesmanArea]
    Info : "AreaName: "
    Width: 10
    ;Local : Field : Medium Prompt : Set as : if @@IsSalesVch then "AreaName :" else "Testing"
    ;Local : Field : HPSalesmanArea : Set as : if (@@IsSales OR @@IsDelNote) then $Area:Ledger:$PartyLedgerName else " "


    [Field: VCHSalesmanArea]
    Use : Name Field
    Skip : Yes
    Set as : $Area:Ledger:$PartyLedgerName
    ;; RETRIVES AREA NAME AND POST IT IN INVOICE


    ;================================================SalesMan Name & MobileNum Invoice Print=======================================
    [*Part: EXPINV Words]
    Lines : EXPINV WordTitle , EXPINV AmtInWords,SalesManName,PhoneNum
    Space Bottom: 0.25


    [Part:lastbal]
    Line: SalesManName
    Line:phoneNum

    [Line: SalesManName]
    Fields: SalesManNamet, SalesManNamed1

    [Field: SalesManNamet]
    Info:"SalesManName"
    Width:10

    [Field: SalesManNamed1]
    Use:Name Field
    Set as: $VCHSalesmanName
    Style: Large Bold

    [Line:phoneNum]
    Field:phoneNumt,PhoneNumd

    [Field:phoneNumt]
    Info:"Phone Number"
    Width:10

    [Field:phoneNumd]
    Use:Name Field
    Set as: $VCHSalMobNum
    Style: Large Bold

    ;[Style: Custom]
    ;Font: Verdana
    ;Bold: Yes
    ;Height: 50


    ;;================= Report Code start from here=====================
    ;====================================================Salesman sales Report==================================================





    [Report: SmReport]
    Use : DSP Template
    Form : PQRReport
    Title : "Salesman Report"
    Set : SVFromDate : $$MonthStart:##SVCurrentDate
    Set : SVToDate : $$MonthEnd:##SVCurrentDate
    Set : SalesManChqVar : "Full"
    Set : SalesManName : ""

    [Form: PQRReport]
    Use : DSP Template
    Parts : PQRReport
    Height : 100% screen
    Width : 100% screen
    Delete : Buttons: ExplodeFlag
    Background: @@SV_RELEASEDLEAFGREEN_PL; Very Light Sea Green
    ;Delete : Bottom Buttons: DSPAutoColumns, RelReports,BudgetAnalysis, ReportConfig
    Bottom Toolbar Buttons : BottomToolBarBtn1, BottomToolBarBtn6, BottomToolBarBtn7, BottomToolBarBtn8, BottomToolBarBtn9, BottomToolBarBtn10, BottomToolBarBtn11, BottomToolBarBtn12,
    Add: Button: Salesmanfilter

    [Part: PQRReport]
    Lines:pQRTitile,PQRBody
    BottomLines : PQRBody Total
    Repeat : PQRBody :pQRSalesManVouchersColl
    CommonBorder: Yes
    Scroll : Vertical
    Total :pQRPartyAmount

    [Line: PQRTitile]
    Use:pQRBody
    Local : Field : Default : Type : String
    Local : Field : Default : Style : Tiny Bold
    Local : Field : Default : Align : Centre
    Local : Field : Default : set as : $$LocaleString:"S. No"
    Local : Field : PQRPartyDate : Set as: $$LocaleString:"Date"
    Local : Field : PQRPartyVchNo : Set as: $$LocaleString:"Vch No."
    Local : Field : PQRPartyName : Set as: $$LocaleString:"Party Name"
    Local : Field : PQRPartySalesMan: Set as: $$LocaleString:"SalesMan"
    Local : Field : PQRPartyVchType : Set as: $$LocaleString:"Vch Type"
    Local : Field : PQRPartyAmount : Set as: $$LocaleString:"Amount"

    Border : Flush Totals

    [Line: PQRBody]
    Field:pQRSno, PQRPartyDate,PQRPartyVchNo,PQRPartyName,PQRPartySalesMan,PQRPartyVchType
    RightField:pQRPartyAmount
    Border :Thin Bottom

    [Field:pQRSno]
    Set as : $$Line
    Width : 1.5 cm
    Align : Center
    Border : Thin Left Right

    [Field: PQRPartyDate]
    Set as : $Date
    Width : 10% Screen
    Align : Right
    ;Style : Tiny
    Border : Thin Left

    [Field: PQRPartyVchNo]
    Set as : $VoucherNumber
    Width : 10% Screen
    Align : Center
    ;Style : Tiny
    Border : Thin Left

    [Field: PQRPartyName]
    Use : Name Field
    Set as : $PartyLedgerName
    Border : Thin Left
    Width : 40% Screen
    Align : Left
    ;Style : Tiny
    Variable: LedgerName
    Display : Ledger Vouchers

    [Field: PQRPartySalesMan]
    Use :Name Field
    Set as :$VCHSalesmanName
    Border : Thin Left
    Width : 20% Screen
    Align : Left
    ;Style : Tiny
    Key : Create SalesmanName

    [Field: PQRPartyVchType]
    Set as : $VoucherTypeName
    Border : Thin Left
    Width : 15% Screen
    Align : Left
    ;Style : Tiny

    [Field: PQRPartyAmount]
    Use : Amount Forex Field
    Set as : $Amount
    Border : Thin Left
    Width : 15% Screen
    Align : Right
    ;Style : Tiny
    Format : "No Zero,DrCr,Symbol," + ##ShowForex


    [Line: PQRBody Total]
    Use:pQRBody
    Local : Field : Default : Type : String
    Local : Field : Default : Style : Tiny Bold
    Local : Field : Default : Align : Centre
    Local : Field : PQRSno : Set as: ""
    Local : Field : PQRPartyDate : Set as: ""
    Local : Field : PQRPartyVchNo : Set as: ""
    Local : Field : PQRPartyName : Set as: "TOTAL"
    Local : Field : PQRPartyName : Align : Centre
    Local : Field : PQRPartySalesMan: Set as: ""
    Local : Field : PQRPartyVchType : Set as: ""
    Local : Field : PQRPartyAmount : Set as: $$Total:pQRPartyAmount
    Border : Flush Totals




    ;============================== Filter ===================================

    [Button:SalesmanFilter]
    Key : Alt+S
    Action : Execute : SalesmanFilter
    Title : Salesman Name

    [Report:SalesmanFilter]
    Form : SalesmanFilter
    ;Set : SalesmanName : ""
    Set : SalesManChqVar : "Filter"

    [Form:SalesmanFilter]
    Part : SalesmanFilter
    No Confirmation : Yes

    [Part:SalesmanFilter]
    Line : SalesmanFilter

    [Line:SalesmanFilter]
    Field : Medium Prompt,SalesmanFilter
    Local : Field : Medium Prompt : Set as : "Select Salesman Name: "

    [Field:SalesmanFilter]
    Table : SalesmanNameCollection,EndOfList
    ShowTable : Always
    Use : Name Field
    Width : 20
    Border : Thin Box
    Variable : SalesmanName
    Modifies : SalesmanName


    ;================================================================================================
    ;===================================== Collections =================================================

    [Collection: PQRSalesManVouchersColl]
    Type : Voucher
    Fetch : Date, VoucherNumber, VoucherTypeName,LedgerName,PartyLedgerName,VCHSalesmanName, LedgerEntries.*
    Filter : PQRSaleManVouchers
    Filter : SalesManFilter

    [System:UDF]
    EnableSalesman : Logical : 1000


    Commission : Number : 1001


    [Variable:SalesManName]
    Type : String

    [Variable:SalesManChqVar]
    Type : String

    [System:Variable]
    SalesManName : ""
    SalesManChqVar : ""



    [System: Formula]
    PQRSaleManVouchers: $$IsSales:$VoucherTypeName OR $$IsCreditNote:$VoucherTypeName
    SalesManWise : $VCHSalesmanName=@@SAlesManEOL
    SalesManFull : $VCHSalesmanName=$VCHSalesmanName
    SAlesManEOL : if $$IsEndOfList:##SalesManName then $VCHSalesmanName Else ##SalesManName
    SalesManFilter : if ##SalesManChqVar="Filter" Then @@SalesManWise Else @@SalesManFull
     



  8. Attached Files:




  9. Amitkumar

    Amitkumar Member


    Dear Sir/ Madam,

    How can i enable this option ? for incentive report...

     




  10. Hi We have the incentive module ready with us. If you want then send inquiry on www.aaradhyasolutions.in
     



Share This Page